Initial commit

2026-03-31 16:53:11 +02:00
commit d0eba1c834
343 changed files with 34443 additions and 0 deletions
@@ -0,0 +1,6 @@
+{pkgs, ...}: {
+  users.users.someone.packages = with pkgs; [
+    alsa-utils
+    easyeffects
+  ];
+}
@@ -0,0 +1,33 @@
+{
+  pkgs,
+  lib,
+  ...
+}:
+
+let
+  configFile   = "mpv/mpv.conf";
+  mpvInputFile = "mpv/input.conf";
+in
+{
+  users.users.someone.packages = with pkgs; [
+    mpv
+    mpvScripts.mpris
+  ];
+
+  xdg.configFile."${configFile}".text =
+    lib.generators.toKeyValue {
+      mkKeyValue = k: v:
+        "${lib.escapeShellArg k}=${lib.escapeShellArg v}";
+      listsAsDuplicateKeys = true;
+    } {
+      profile = "gpu-hq";
+      volume  = "100";
+    };
+
+  xdg.configFile."${mpvInputFile}".text = ''
+    l af add @pan:stereo|c0=c0|c1=c0
+    r af add @pan:stereo|c0=c1|c1=c1
+    c show-text "Chapters:\n''${chapter-list}"
+    s ignore
+  '';
+}
@@ -0,0 +1,34 @@
+{pkgs, ...}: let
+  obsBase = pkgs.obs-studio.override {
+    pipewireSupport = true;
+    browserSupport = true;
+  };
+
+  plugins = with pkgs.obs-studio-plugins; [
+    obs-gstreamer
+    obs-pipewire-audio-capture
+    obs-vaapi
+  ];
+
+  obsPluginEnv = pkgs.buildEnv {
+    name = "obs-studio-with-plugins-env";
+    paths = plugins;
+  };
+
+  obsWrapped = pkgs.symlinkJoin {
+    name = "obs-studio-wrapped";
+    paths = [obsBase];
+    buildInputs = [pkgs.makeWrapper];
+
+    postBuild = ''
+      wrapProgram $out/bin/obs \
+        --set OBS_PLUGINS_PATH "${obsPluginEnv}/lib/obs-plugins" \
+        --set OBS_PLUGINS_DATA_PATH "${obsPluginEnv}/share/obs/obs-plugins" \
+        --add-flags "--ozone-platform=wayland"
+    '';
+  };
+in {
+  users.users.someone.packages = [
+    obsWrapped
+  ];
+}
@@ -0,0 +1,40 @@
+{pkgs, ...}: let
+  configFile = "pipewire/pipewire.conf.d/99-input-denoising.conf";
+in {
+  users.users.someone.packages = with pkgs; [
+    rnnoise
+    rnnoise-plugin
+  ];
+
+  xdg.configFile."${configFile}".text = builtins.toJSON {
+    "context.modules" = [
+      {
+        "name" = "libpipewire-module-filter-chain";
+        "args" = {
+          "node.description" = "Noise Canceling source";
+          "media.name" = "Noise Canceling source";
+          "filter.graph" = {
+            "nodes" = [
+              {
+                "type" = "ladspa";
+                "name" = "rnnoise";
+                "plugin" = "${pkgs.rnnoise-plugin}/lib/ladspa/librnnoise_ladspa.so";
+                "label" = "noise_suppressor_stereo";
+                "control" = {"VAD Threshold (%)" = 70.0;};
+              }
+            ];
+          };
+          "audio.position" = ["FL" "FR"];
+          "capture.props" = {
+            "node.name" = "effect_input.rnnoise";
+            "node.passive" = true;
+          };
+          "playback.props" = {
+            "node.name" = "effect_output.rnnoise";
+            "media.class" = "Audio/Source";
+          };
+        };
+      }
+    ];
+  };
+}