filters for unix(linux)

Modified Files: filteri.cpp filter/ctojr.h linker.cpp linker.h mem.cpp mem.h p_lx_elf.cpp p_lx_elf.h p_lx_exc.cpp p_lx_exc.h p_lx_sh.cpp p_lx_sh.h p_unix.cpp packer.cpp packer.h packhead.cpp stub/Makefile stub/macros.ash stub/l_lx_elf.c stub/l_lx_elf86.asm stub/l_lx_elf86.lds stub/l_lx_exec.c stub/l_lx_exec86.asm stub/l_lx_exec86.lds stub/l_lx_sh86.asm stub/l_lx_sh86.lds Added Files: filter/ctok.h stub/fold_elf86.asm stub/fold_exec86.asm stub/fold_sh86.asm committer: jreiser <jreiser> 979796725 +0000
2001-01-18 05:45:25 +00:00
parent 4d45677160
commit df9db96bd1
30 changed files with 2014 additions and 1105 deletions
@@ -0,0 +1,127 @@
+;  fold_elf86.asm -- linkage to C code to process Elf binary
+;
+;  This file is part of the UPX executable compressor.
+;
+;  Copyright (C) 2000-2001 John F. Reiser
+;  All Rights Reserved.
+;
+;  UPX and the UCL library are free software; you can redistribute them
+;  and/or modify them under the terms of the GNU General Public License as
+;  published by the Free Software Foundation; either version 2 of
+;  the License, or (at your option) any later version.
+;
+;  This program is distributed in the hope that it will be useful,
+;  but WITHOUT ANY WARRANTY; without even the implied warranty of
+;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;  GNU General Public License for more details.
+;
+;  You should have received a copy of the GNU General Public License
+;  along with this program; see the file COPYING.
+;  If not, write to the Free Software Foundation, Inc.,
+;  59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+;
+;  Markus F.X.J. Oberhumer   Laszlo Molnar           John F. Reiser
+;  markus@oberhumer.com      ml1050@cdata.tvnet.hu   jreiser@BitWagon.com
+;
+
+%define szElf32_Ehdr 0x34
+%define szElf32_Phdr 8*4
+%define p_memsz  5*4
+%define a_val  4
+
+%define __NR_munmap   91
+
+;; control just falls through, after this part and compiled C code
+;; are uncompressed.
+
+fold_begin:
+        ; patchLoader will modify to be
+        ;   dword sz_uncompressed, sz_compressed
+        ;   byte  compressed_data...
+
+        pop eax  ; discard &sz_uncompressed
+        pop eax  ; discard  sz_uncompressed
+
+; Move argc,argv,envp down so that we can insert more Elf_auxv entries.
+; ld-linux.so.2 depends on AT_PHDR and AT_ENTRY, for instance
+
+%define OVERHEAD 2048
+%define MAX_ELF_HDR 512
+
+        mov esi, esp
+        sub esp, byte 6*8  ; AT_PHENT, AT_PHNUM, AT_PAGESZ, AT_ENTRY, AT_PHDR, AT_NULL
+        mov edi, esp
+        call do_auxv
+
+        sub esp, dword MAX_ELF_HDR + OVERHEAD
+        push esp  ; argument: temp space
+        push edi  ; argument: AT_next
+        push ebp  ; argument: &decompress
+        push edx  ; argument: my_elfhdr
+        add edx, [p_memsz + szElf32_Ehdr + edx]
+        push edx  ; argument: uncbuf
+EXTERN upx_main
+        call upx_main  ; entry = upx_main(uncbuf, my_elfhdr, &decompress, AT_next, tmp_ehdr)
+        pop esi  ; decompression buffer == (p_vaddr + p_memsz) of stub
+        pop ebx  ; my_elfhdr
+        add esp, dword 3*4 + MAX_ELF_HDR + OVERHEAD  ; remove 3 params, temp space
+        push eax  ; save entry address
+
+        mov edi, [a_val + edi]  ; AT_PHDR
+find_hatch:
+        push edi
+EXTERN make_hatch
+        call make_hatch  ; find hatch = make_hatch(phdr)
+        pop ecx  ; junk the parameter
+        add edi, byte szElf32_Phdr  ; prepare to try next Elf32_Phdr
+        test eax,eax
+        jz find_hatch
+        xchg eax,edx  ; edx= &hatch
+
+; _dl_start and company (ld-linux.so.2) assumes that it has virgin stack,
+; and does not initialize all its stack local variables to zero.
+; Ulrich Drepper (drepper@cyngus.com) has refused to fix the bugs.
+; See GNU wwwgnats libc/1165 .
+
+%define  N_STKCLR (0x100 + MAX_ELF_HDR + OVERHEAD)/4
+        lea edi, [esp - 4*N_STKCLR]
+        pusha  ; values will be zeroed
+        mov ecx, N_STKCLR
+        xor eax,eax
+        rep stosd
+
+        mov ecx,esi  ; my p_vaddr + p_memsz
+        mov bh,0  ; round down to 64KB boundary
+        sub ecx,ebx  ; length to unmap
+        push byte __NR_munmap
+        pop eax
+        jmp edx  ; unmap ourselves via escape hatch, then goto entry
+
+do_auxv:  ; entry: %esi=src = &argc; %edi=dst.  exit: %edi= &AT_NULL
+        ; cld
+
+L10:  ; move argc+argv
+        lodsd
+        stosd
+        test eax,eax
+        jne L10
+
+L20:  ; move envp
+        lodsd
+        stosd
+        test eax,eax
+        jne L20
+
+L30:  ; move existing Elf32_auxv
+        lodsd
+        stosd
+        test eax,eax  ; AT_NULL ?
+        lodsd
+        stosd
+        jne L30
+
+        sub edi, byte 8  ; point to AT_NULL
+        ret
+
+; vi:ts=8:et:nowrap
+