jory
205a1ccc8f
- Add prepare-commit-msg git hook that generates conventional commit messages - Modularize fish configuration with separate conf.d files - Convert configuration files from .text to .source format for structured data - Add sops-nix SOPS configuration with explicit secret definitions - Upgrade age identity to single key file management approach - Add system activation script for age key management - Generate .sops.yaml for SOPS creation rules - Restructure README.md with improved table and cleaner formatting - Refactor config files to use pkgs.formats.json/toml generators - Implement YAML format for ashell and walker service configurations - Update SSH config source to use sops secrets - Convert zed and other config files to use structured .source format
99 lines
2.5 KiB
Nix
99 lines
2.5 KiB
Nix
{
|
|
self,
|
|
inputs,
|
|
...
|
|
}: let
|
|
# shorten paths
|
|
inherit (inputs.nixpkgs.lib) nixosSystem;
|
|
lib = inputs.nixpkgs.lib;
|
|
# Server uses its own pinned 24.05 nixpkgs (kept isolated from the laptop's unstable)
|
|
nixosSystem24 = inputs.nixos-24-05.lib.nixosSystem;
|
|
unstablePkgs = import inputs.nixpkgs-unstable {system = "x86_64-linux";};
|
|
mod = "${self}/system";
|
|
home = "${self}/home";
|
|
|
|
# get the basic config to build on top of
|
|
inherit (import "${self}/system") tty desktop laptop;
|
|
|
|
# get these into the module system
|
|
specialArgs = {inherit inputs self;};
|
|
|
|
# shared modules for all configurations
|
|
sharedModules = [
|
|
./aesthetic
|
|
"${mod}/services/gnome-services.nix"
|
|
"${mod}/core/limine.nix"
|
|
"${home}"
|
|
inputs.sops-nix.nixosModules.sops
|
|
];
|
|
in {
|
|
flake.nixosConfigurations = {
|
|
# TTY: desktop headless (no GUI)
|
|
tty = nixosSystem {
|
|
inherit specialArgs;
|
|
modules = tty ++ sharedModules;
|
|
};
|
|
|
|
# Desktop: desktop with GUI
|
|
desktop = nixosSystem {
|
|
inherit specialArgs;
|
|
modules = desktop ++ sharedModules;
|
|
};
|
|
|
|
# Laptop: laptop with GUI + battery + bluetooth
|
|
laptop = nixosSystem {
|
|
inherit specialArgs;
|
|
modules =
|
|
laptop
|
|
++ sharedModules
|
|
++ [
|
|
"${mod}/services/location.nix"
|
|
];
|
|
};
|
|
|
|
# Laptop UEFI: explicit UEFI boot mode
|
|
laptop-uefi = nixosSystem {
|
|
inherit specialArgs;
|
|
modules =
|
|
laptop
|
|
++ sharedModules
|
|
++ [
|
|
"${mod}/services/location.nix"
|
|
({ config, ... }: {
|
|
boot.loader.limine.bootMode = "uefi";
|
|
})
|
|
];
|
|
};
|
|
|
|
# Laptop BIOS: explicit BIOS boot mode
|
|
laptop-bios = nixosSystem {
|
|
inherit specialArgs;
|
|
modules =
|
|
laptop
|
|
++ sharedModules
|
|
++ [
|
|
"${mod}/services/location.nix"
|
|
({ config, ... }: {
|
|
boot.loader.limine.bootMode = "bios";
|
|
boot.loader.limine.biosDevice = "/dev/nvme0n1";
|
|
})
|
|
];
|
|
};
|
|
|
|
# Server: severijnse.eu (Hetzner) — fully isolated under servers/hetzner/.
|
|
# Uses nixos-24.05 + disko + sops-nix and does NOT inherit the laptop's shared modules.
|
|
hetzner = nixosSystem24 {
|
|
system = "x86_64-linux";
|
|
specialArgs = {
|
|
inherit inputs self unstablePkgs;
|
|
};
|
|
modules = [
|
|
inputs.disko.nixosModules.disko
|
|
inputs.sops-nix.nixosModules.sops
|
|
"${self}/servers/hetzner/hosts/hetzner/hardware-configuration.nix"
|
|
"${self}/servers/hetzner/hosts/hetzner/default.nix"
|
|
];
|
|
};
|
|
};
|
|
}
|